Anda di sini

Elektronika

Tutorial Arduino Mengukur Penggunaan Listrik Rumah Dengan Current Transformer

Aditya Suranata - 19 Mei 2018 18:29:37 0

Untuk dapat mengukur penggunaan listrik di rumah, kita bisa melakukannya dengan melibatkan penggunaan arus. Dengan melibatkan penggunaan arus dalam perhitungan eletronika, maka dapat diketahui berapa daya yang digunakan oleh perangkat listrik di rumah. Mengukur penggunaan arus listrik pada jenis listrik AC (alternating current) dari PLN menggunakan mikrokontroler seperti Arduino merupakan tugas yang agak sedikit rumit. Hal ini disebabkan karena karakteristrik dari listrik AC berbeda dengan listrik DC yang tidak berubah-ubah, dan juga listrik AC dari PLN merupakan listrik bertegangan tinggi (220Volt) sehingga diperlukan penanganan ekstra agar tidak membahayakan dan dapat dibaca oleh Arduino yang beroperasi di tegangan DC rendah (5 Volt).

Karena perbedaan tegangan kerja, maka diperlukan alat yang bernama current transformer (CT) untuk dapat merubah tegangan PLN menjadi tegangan aman yang dapat dibaca oleh Arduino. Penggunaan CT secara langsung pada Arduino juga tidak dimungkinkan, diperlukan komponen / rangkaian elektronik tambahan untuk itu. Namun demikian, tugas ini menjadi tidak begitu menyusahkan bagi para hobist yang ingin belajar. Karena kita dapat menggunakan modul atau rangkaian CT siap pakai yang bisa dihubungkan langsung dengan Arduino. Seperti misalnya modul TA12-100 buatan Itead memungkinkan kita untuk dapat melakukan transformasi arus dengan perbandingan 1000:1. Luaran dari CT ini memiliki resistensi sebesar 200 Ohm. Besaran arus selanjutnya dapat dikalkulasikan dengan mengukur voltage drop pada resistor tersebut. Pada dasarnya, modul jenis ini sangat berguna apabila kita akan mengukur listrik AC dengan frekuensi yang digunakan oleh PLN.

Pengkabelan Modul TA12-100 Pada Arduino

PERHATIAN! Tutorial ini dapat memaparkan Anda pada listrik mematikan! Mohon berhati-hati.

Sensor arus AC PLN ini dapat mengukur arus hingga maksimal 5 Ampere. Pada umumnya listrik di rumah yang memiliki daya 900VA memiliki arus maksimal sebesar 4 Amper. Modul sensor ini memerlukan dua kabel yang terhubung ke Arduino untuk dapat mengukur arus. Dan kabel fase PLN dilewatkan ke lubang bagian dalam dari CT.

Untuk memperjelas, perhatikan gambar pengkabelan di bawah ini (klik untuk memperbesar). Kuncinya adalah kamu harus menggunakan beban AC yang tidak lebih besar dari 5 Ampere. Untuk pengujian pertama, ada baiknya kita menggunakan sebuah lampu rumah untuk mengujinya yang pada umumnya hanya menggunakan arus tidak lebih dari 1 ampere.

Kode Program Sensor Arus Current Transformer TA12-100 Untuk Arduino

Setelah pengkabelan selesai, selanjutnya dapat dilanjutkan ke tahap pemrograman. Silahkan pelajari kode program berikut untuk mengetahui bagaimana cara kerjanya. Perlu diingat, bahwa hasilnya sangat bergantung pada pengukuran arus dari gelombang sinusidal atau hanya untuk listrik AC.

Inti dari yang dilakukan oleh kode program:

  • Mengukur tengangan peak yang hilang pada resistor 200 Ohm yang berada pada bagian luaran dari transformer.
  • Mengonversi tegangan yang hilang itu menjadi arus dengan menggunakan hukum Ohm: I = V / R (I = arus, V = tegangan, R = hambatan).
  • Mengalikan tengangan peak dengan 0,707 untuk mendapatkan tegangan RMS pada resistor. (0,707 sebagai faktor yang hanya berlaku untuk gelombang sinus).
  • Mengalikan arus RMS dengan 1000 untuk mendapatkan nilai arus yang mengalir pada kabel listrik yang diukur. (Karena CT yang digunakan memiliki rasio 1000:1).

Berikut kode program yang dapat diunggah ke Arduino.

// Henry's Bench TA-1200 AC Current Sensor Tutorial


int sensorTA12 = A0; // Analog input pin that sensor is attached to

float nVPP;   // Voltage measured across resistor
float nCurrThruResistorPP; // Peak Current Measured Through Resistor
float nCurrThruResistorRMS; // RMS current through Resistor
float nCurrentThruWire;     // Actual RMS current in Wire

void setup() 
 {
   Serial.begin(9600); 
   pinMode(sensorTA12, INPUT);
 }
 
 
 void loop() 
 {
   
   
   nVPP = getVPP();
   
   /*
   Use Ohms law to calculate current across resistor
   and express in mA 
   */
   
   nCurrThruResistorPP = (nVPP/200.0) * 1000.0;
   
   /* 
   Use Formula for SINE wave to convert
   to RMS 
   */
   
   nCurrThruResistorRMS = nCurrThruResistorPP * 0.707;
   
   /* 
   Current Transformer Ratio is 1000:1...
   
   Therefore current through 200 ohm resistor
   is multiplied by 1000 to get input current
   */
   
   nCurrentThruWire = nCurrThruResistorRMS * 1000;

   
   Serial.print("Volts Peak : ");
   Serial.println(nVPP,3);
 
   
   Serial.print("Current Through Resistor (Peak) : ");
   Serial.print(nCurrThruResistorPP,3);
   Serial.println(" mA Peak to Peak");
   
   Serial.print("Current Through Resistor (RMS) : ");
   Serial.print(nCurrThruResistorRMS,3);
   Serial.println(" mA RMS");
   
   Serial.print("Current Through Wire : ");
   Serial.print(nCurrentThruWire,3);
   Serial.println(" mA RMS");
   
   Serial.println();
 }


 /************************************ 
In order to calculate RMS current, we need to know
the peak to peak voltage measured at the output across the
200 Ohm Resistor

The following function takes one second worth of samples
and returns the peak value that is measured
 *************************************/
 
 
float getVPP()
{
  float result;
  int readValue;             //value read from the sensor
  int maxValue = 0;          // store max value here
   uint32_t start_time = millis();
   while((millis()-start_time) < 1000) //sample for 1 Sec
   {
       readValue = analogRead(sensorTA12);
       // see if you have a new maxValue
       if (readValue > maxValue) 
       {
           /*record the maximum sensor value*/
           maxValue = readValue;
       }
   }
   
   // Convert the digital data to a voltage
   result = (maxValue * 5.0)/1024.0;
  
   return result;
 }

Lakukan verifikasi dan setelah selesai mengunggah kodenya, buka serial monitor pada Arduino IDE untuk melihat hasilnya. Sebagai contoh hasil pembacaan arus dari program ini terlihat seperti gambar berikut:

Untuk mengetahui penggunaan listriknya, nilai dari arusnya (Current Through Wire) pada contoh hasil dapat dikalikan dengan tegangan. Misalnya:

Arus : 2433 mA = 2,4 A

Tegangan: 220V

Watt = Arus x Tegangan, 2,4 x 220 = 528 Watt

Sehingga dapat disimpulkan bahwa beban menggunakan daya sebesar 528 Watt. Selanjutnya dapat pula dikalkulasikan biaya listriknya dengan mengkalkulasikan dengan waktu / durasi penggunaan sehingga didapatkan nilai dalam Watt Hours.

Terakhir, nilai dalam Watt Hours dapat dikalkulasikan dengan tarif listrik PLN dalam kWh / kilo watt hours, sehingga didapatkan nilai berupa biaya dalam rupiah.

Sekian sedikit catatan singkat ini, nantikan tutorial selanjutnya yang berkaitan dengan smart home yang juga menggunakan isi dari catatan ini. Emo 58

Referensi: http://henrysbench.capnfatz.com/henrys-bench/arduino-current-measurement...

2.427
Image

Aditya Suranata

Aditya suka menulis, bukan hanya sekedar hobi, menulis menjadi medianya untuk mencurahkan pikiran dan perasaan. Di TutorKeren.com kebanyakan menyumbang tulisan sesuai dengan minat dan keahliannya yaitu pada kategori pemrograman dan elektronika. Selain itu juga gemar menulis mengenai hal-hal umum, seperti ilmu alam, sosial dan beberapa pengalamannya yang mungkin bisa berguna untuk orang lain.

Artikel Menarik Lainnya
Mari Gabung

Halo Emo 51 , Ada yang ingin disampaikan? Jangan sungkan untuk gabung diskusi ini. Silahkan Login dulu atau Daftar baru.